Initial commit

scripts/cmake/compilerwarnings.cmake

@@ -0,0 +1,106 @@
+include_guard()
+
+function( target_enable_warnings _target )
+    if(MSVC)
+        target_compile_options(
+            ${_target} 
+            PUBLIC
+            /W4 # Baseline reasonable warnings
+            /w14242 # 'identifier': conversion from 'type1' to 'type1', possible loss of data
+            /w14254 # 'operator': conversion from 'type1:field_bits' to 'type2:field_bits', possible loss of data
+            /w14263 # 'function': member function does not override any base class virtual member function
+            /w14265 # 'classname': class has virtual functions, but destructor is not virtual instances of this class may not
+                    # be destructed correctly
+            /w14287 # 'operator': unsigned/negative constant mismatch
+            /we4289 # nonstandard extension used: 'variable': loop control variable declared in the for-loop is used outside
+                    # the for-loop scope
+            /w14296 # 'operator': expression is always 'boolean_value'
+            /w14311 # 'variable': pointer truncation from 'type1' to 'type2'
+            /w14545 # expression before comma evaluates to a function which is missing an argument list
+            /w14546 # function call before comma missing argument list
+            /w14547 # 'operator': operator before comma has no effect; expected operator with side-effect
+            /w14549 # 'operator': operator before comma has no effect; did you intend 'operator'?
+            /w14555 # expression has no effect; expected expression with side- effect
+            /w14619 # pragma warning: there is no warning number 'number'
+            /w14640 # Enable warning on thread un-safe static member initialization
+            /w14826 # Conversion from 'type1' to 'type_2' is sign-extended. This may cause unexpected runtime behavior.
+            /w14905 # wide string literal cast to 'LPSTR'
+            /w14906 # string literal cast to 'LPWSTR'
+            /w14928 # illegal copy-initialization; more than one user-defined conversion has been implicitly applied
+            /permissive- # standards conformance mode for MSVC compiler.
+        )
+    elseif(CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
+        target_compile_options(
+            ${_target} 
+            INTERFACE
+            -Wall
+            -Wextra # reasonable and standard
+            -Wextra-semi # Warn about semicolon after in-class function definition.
+            -Wshadow # warn the user if a variable declaration shadows one from a parent context
+            -Wnon-virtual-dtor # warn the user if a class with virtual functions has a non-virtual destructor. This helps
+
+            # catch hard to track down memory errors
+            -Wold-style-cast # warn for c-style casts
+            -Wcast-align # warn for potential performance problem casts
+            -Wunused # warn on anything being unused
+            -Woverloaded-virtual # warn if you overload (not override) a virtual function
+            -Wpedantic # warn if non-standard C++ is used
+            -Wconversion # warn on type conversions that may lose data
+            -Wsign-conversion # warn on sign conversions
+            -Wnull-dereference # warn if a null dereference is detected
+            -Wdouble-promotion # warn if float is implicit promoted to double
+            -Wformat=2 # warn on security issues around functions that format output (ie printf)
+            -Wimplicit-fallthrough # warn on statements that fallthrough without an explicit annotation
+        )
+    elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
+        target_compile_options(
+            ${_target} 
+            INTERFACE
+            -Wall
+            -Wextra # reasonable and standard
+            -Wextra-semi # Warn about semicolon after in-class function definition.
+            -Wshadow # warn the user if a variable declaration shadows one from a parent context
+            -Wnon-virtual-dtor # warn the user if a class with virtual functions has a non-virtual destructor. This helps
+
+            # catch hard to track down memory errors
+            -Wold-style-cast # warn for c-style casts
+            -Wcast-align # warn for potential performance problem casts
+            -Wunused # warn on anything being unused
+            -Woverloaded-virtual # warn if you overload (not override) a virtual function
+            -Wpedantic # warn if non-standard C++ is used
+            -Wconversion # warn on type conversions that may lose data
+            -Wsign-conversion # warn on sign conversions
+            -Wnull-dereference # warn if a null dereference is detected
+            -Wdouble-promotion # warn if float is implicit promoted to double
+            -Wformat=2 # warn on security issues around functions that format output (ie printf)
+            -Wimplicit-fallthrough # warn on statements that fallthrough without an explicit annotation
+            -Wmisleading-indentation # warn if indentation implies blocks where blocks do not exist
+            -Wduplicated-cond # warn if if / else chain has duplicated conditions
+            -Wduplicated-branches # warn if if / else branches have duplicated code
+            -Wlogical-op # warn about logical operations being used where bitwise were probably wanted
+            -Wuseless-cast # warn if you perform a cast to the same type
+        )
+    endif()
+endfunction()
+
+function(target_warnings_as_errors _target)
+    if(MSVC)
+        target_compile_options(
+            ${_target}
+            PUBLIC
+            /WX
+        )
+    elseif(CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
+        target_compile_options(
+            ${_target}
+            PUBLIC
+            -Werror
+        )
+    elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
+        target_compile_options(
+            ${_target}
+            PUBLIC
+            -Werror
+        )
+    endif()
+endfunction()

scripts/cmake/googletest.cmake

@@ -0,0 +1,18 @@
+include_guard()
+
+include(FetchContent)
+FetchContent_Declare(
+  googletest
+  GIT_REPOSITORY https://github.com/google/googletest.git
+  GIT_TAG        58d77fa8070e8cec2dc1ed015d66b454c8d78850 # release-1.12.1
+)
+# For Windows: Prevent overriding the parent project's compiler/linker settings
+set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
+FetchContent_MakeAvailable(googletest)
+
+set_property(TARGET 
+	gtest 
+	gtest_main 
+	gmock
+	gmock_main
+	PROPERTY FOLDER GoogleTest)

scripts/cmake/precompiled.cmake

@@ -0,0 +1,8 @@
+include_guard()
+
+function( target_precompiled_header _target _header _source )
+	if( MSVC )
+		set_target_properties( ${_target} PROPERTIES COMPILE_FLAGS "/Yu${_header}" )
+		set_source_files_properties( ${_source} PROPERTIES COMPILE_FLAGS "/Yc${_header}" )
+	endif()
+endfunction()

scripts/cmake/sanitizers.cmake

@@ -0,0 +1,20 @@
+include_guard()
+
+function( target_enable_sanitizers _target )
+    if( MSVC )
+        string(FIND "$ENV{PATH}" "$ENV{VSINSTALLDIR}" index_of_vs_install_dir)
+
+        if("${index_of_vs_install_dir}" STREQUAL "-1")
+            message(
+                SEND_ERROR
+                "Using MSVC sanitizers requires setting the MSVC environment before building the project. Please manually open the MSVC command prompt and rebuild the project."
+            )
+        endif()
+
+        target_compile_options(${_target} PUBLIC /fsanitize=address /Zi /INCREMENTAL:NO)
+        target_link_options(${_target} PUBLIC /INCREMENTAL:NO)
+    else()
+        target_compile_options(${_target} INTERFACE -fsanitize=address,leak,undefined)
+        target_link_options(${_target} INTERFACE -fsanitize=address,leak,undefined)
+    endif()
+endfunction()

scripts/cmake/staticanalysis.cmake

@@ -0,0 +1,16 @@
+include_guard()
+
+function(target_enable_static_analysis _target)
+    set(_VS_CLANG_TIDY "false")
+    find_program(CLANGTIDY clang-tidy)
+    if(CLANGTIDY)
+        set(_VS_CLANG_TIDY "true")
+    endif()
+    set_target_properties(
+        ${_target}
+        PROPERTIES
+        VS_GLOBAL_EnableMicrosoftCodeAnalysis true
+        VS_GLOBAL_CodeAnalysisRuleSet "AllRules.ruleset"
+        VS_GLOBAL_EnableClangTidyCodeAnalysis "${_VS_CLANG_TIDY}"
+    )
+endfunction()